EnigmA Amiga Run 1995 October/EnigmA AMIGA RUN 01 (1995)(G.R. Edizioni)(IT)[!][issue 1995-10][Aminet 7].iso/Aminet/dev/amos/AMOSL0595.lzh/AMOSLIST/[e-mail]_Sat May 13 23:11:08 1995.msg

Internet Message Format | 1995-06-01 | 5KB

Received: from svcs1.digex.net by www1.access.digex.net with SMTP id AA08107
  (5.67b8/IDA-1.5); Sat, 13 May 1995 23:11:07 -0400
Received: by svcs1.digex.net id AA11040
  (5.67b8/IDA-1.5 for amos-out); Sat, 13 May 1995 19:16:57 -0400
Received: from www1.access.digex.net by svcs1.digex.net with SMTP id AA11036
  (5.67b8/IDA-1.5 for <[e-mail]>); Sat, 13 May 1995 19:16:55 -0400
Received: from pan.otol.fi by www1.access.digex.net with SMTP id AA29087
  (5.67b8/IDA-1.5 for <[e-mail]>); Sat, 13 May 1995 19:16:47 -0400
Received: from janus.otol.fi ([e-mail] [193.64.226.249]) by pan.otol.fi (8.6.12/8.6.9) with ESMTP id CAA23851 for <[e-mail]>; Sun, 14 May 1995 02:16:51 +0300
Received: (from tumu@localhost) by janus.otol.fi (8.6.9/8.6.9) id CAA14221; Sun, 14 May 1995 02:16:41 +0300
Date: Sun, 14 May 1995 02:16:41 +0300 (EET DST)
From: Tumu / BFB <[e-mail]>
To: AMOS Mailing list <[e-mail]>
Subject: REQTOOLS INTERFACE FOR AMOSPRO
Message-Id: <[e-mail]>
Mime-Version: 1.0
Content-Type: TEXT/PLAIN; charset=US-ASCII
Status: RO
X-Status:


Here it is, Reqtools interface for AmosPro.

I will update it like adding matchpatterns, but it hasn't got much hurry.

If you're using this piece of code in your progs, please credit me in
information texts.

This piece of code is PUBLIC DOMAIN, so you can't take any money from it
except some cost for disks and postage.

    Tumu / BFB Team <[e-mail]>

------------------------ cut here --------------------------

' reqtools interface by tumu / bfb team <[e-mail]>
' version 1.0 - public domain

' bfb team productions 1995
' bfb team www page: http://lyyra.kempele.fi/~quaid/

' reqtools.library is copyrighted by Nico Francois

' requires make's lib extension! _rtfilereq uses it's mem allocation routines
'                            (reserves 108 bytes for filename)

' make's lib can be ftped from nic.funet.fi
'                              /pub/amiga/programming/amos/makelib.lha

' procedures:
'             _rtallocrequest[type_of_requester]
'             ; allocates needed buffers for requesters
'               type = 0 - file requester
'                      1 - easy requester
'                      2 - font requester (not available)
'                      3 - screenmode req. (not available)
'             ; returns in Param the address of the buffer or null if
'               no memory

'             _rtezrequest[requester_string,gadget_strings,titlebar_str,
'                          request_buffer]
'             ; use easy requester
'               requester_string - requester string
'               gadget_string    - gadget string (gads seperated by '|')
'                                  (example: "Ok|Cancel")
'               titlebar_str     - titlebar string
'               request_buffer   - address returned by _rtallocrequest

'             _rtfilerequest[titlestr,request_buffer]
'             ; use file requester
'               titlestr - title string
'               request_buffer - address returned by _rtallocrequest
'             ; return: returns 1 in Param if user selected a file
'                       _rtfile$ contains filename
'                       _rtdir$ contains directoryname

'             _rtfreerequest[request_buffer]
'             ; deallocates request buffer
'               request_buffer - address returned by _rtallocrequest

Amos To Back

Lib Open 1,"reqtools.library",0

_RTALLOCREQUEST[0]
_REQBUFFER=Param

If _REQBUFFER<=0
   Amos To Front
   Print "no enough mem for reqbuffer"
   End
End If

_RTFILEREQUEST["BFB Team productions 1995",_REQBUFFER]

Print Param,_RTDIR$+"/"+_RTFILE$

_RTFREEREQUEST[_REQBUFFER]

Amos To Front

Procedure _RTALLOCREQUEST[TYPE]
   ' rt_filereq - equ 0 ; file requester
   ' rt_reqinfo - equ 1 ; easy requester

   Dreg(0)=TYPE
   Areg(0)=0

   RES=Lib Call(1,-$1E)

End Proc[RES]
Procedure _RTEZREQUEST[_REQ$,_GADS$,_TITLE$,_REQBUFFER]

   Areg(1)=Varptr(_REQ$)
   Areg(2)=Varptr(_GADS$)
   Areg(3)=_REQBUFFER
   Areg(4)=0
   Areg(0)=0

   X=Free
   Loke _REQBUFFER+12,Varptr(_TITLE$)

   RES=Lib Call(1,-$42)

End Proc[RES]
Procedure _RTFILEREQUEST[_TITLE$,_REQBUFFER]

   Shared _RTFILE$,_RTDIR$,_RTFILENAMEPTR

   If _RTFILENAMEPTR=0
      _RTFILENAMEPTR=Ma Malloc(108,Mem Public+Mem Clear)
   End If

   If _RTFILENAMEPTR=0
      Pop Proc[-1]
   End If

   _TITLE$=_TITLE$+Chr$(0)

   Areg(0)=0
   Areg(1)=_REQBUFFER
   Areg(2)=_RTFILENAMEPTR

   X=Free
   Areg(3)=Varptr(_TITLE$)

   RES=Lib Call(1,-$36)

   If RES=1
      _RTFILE$=Elmem$(_RTFILENAMEPTR,108,0)
      _RTDIR$=Elmem$(Leek(_REQBUFFER+16),108-Len(_RTFILE$),0)
   End If

End Proc[RES]
Procedure _RTFREEREQUEST[_REQBUFFER]

   Shared _RTFILENAMEPTR

   Areg(1)=_REQBUFFER

   RES=Lib Call(1,-$24)

   If _RTFILENAMEPTR>0 Then Ma Free _RTFILENAMEPTR

End Proc